variable "project_id" {
  description = "STACKIT project ID"
  type        = string
}

variable "name" {
  description = "Cluster name"
  type        = string
}

variable "node_pools" {
  description = "List of node pool configs"
  type = list(object({
    name               = string
    machine_type       = string
    availability_zones = list(string)
    minimum            = number
    maximum            = number

    allow_system_components = optional(bool)
    cri                     = optional(string)
    labels                  = optional(map(string))
    max_surge               = optional(number)
    max_unavailable         = optional(number)
    os_name                 = optional(string)
    os_version_min          = optional(string)
    taints = optional(list(object({
      effect = string
      key    = string
      value  = optional(string)
    })))
    volume_size = optional(number)
    volume_type = optional(string)
  }))
}

variable "kubernetes_version_min" {
  description = "Minimum Kubernetes version"
  type        = string
  default     = null
}

variable "hibernations" {
  description = "Hibernation schedules"
  type = list(object({
    start    = string
    end      = string
    timezone = optional(string)
  }))
  default = null
}

variable "maintenance" {
  description = "Maintenance window settings"
  type = object({
    enable_kubernetes_version_updates    = bool
    enable_machine_image_version_updates = bool
    start                                = string
    end                                  = string
  })
  default = null
}

variable "extensions" {
  description = "Extensions config"
  type = object({
    acl = optional(object({
      enabled       = bool
      allowed_cidrs = list(string)
    }))
    argus = optional(object({
      enabled           = bool
      argus_instance_id = string
    }))
    dns = optional(object({
      enabled = bool
      zones   = optional(list(string))
    }))
  })
  default = null
}

variable "default_region" {
  description = "Resource region override"
  type        = string
  default     = null
}