variable "project_id" {
  description = "STACKIT project ID"
  type        = string
}

variable "name" {
  description = "Instance name (DNS-1035 compliant)"
  type        = string

  validation {
    condition     = length(regexall("^[a-z]([-a-z0-9]*[a-z0-9])?$", var.name)) > 0
    error_message = <<EOT
      The name must be a valid DNS-1035 label:
      - only lower-case letters, digits or '-'
      - must start with a letter
      - must end with a letter or digit
      EOT
  }
}

variable "ver" {
  description = "PostgreSQL version"
  type        = number
}

variable "flavor" {
  description = "Compute flavor (cpu, ram GB)"
  type = object({
    cpu = number
    ram = number
  })
}

variable "storage" {
  description = "Storage settings (class, size GB)"
  type = object({
    class = string
    size  = number
  })
}

variable "replicas" {
  description = "Number of instance replicas"
  type        = number
}

variable "acl" {
  description = "Allowed CIDR list for instance access"
  type        = list(string)
}

variable "backup_schedule" {
  description = "Backup schedule string"
  type        = string
}

variable "users" {
  description = "Database users (username, roles)"
  type = list(object({
    username = string
    roles    = set(string)
  }))
  default = []

  validation {
    condition = alltrue([
      for user in var.users : user.username != "admin"
    ])
    error_message = "The username 'admin' is reserved and cannot be used."
  }
}

variable "databases" {
  description = "Databases to create (name, owner)"
  type = list(object({
    name  = string
    owner = string
  }))
  default = []

  validation {
    condition = alltrue([
      for db in var.databases : length(regexall("^[a-z]([-a-z0-9]*[a-z0-9])?$", db.name)) > 0
    ])
    error_message = <<EOT
      The name must be a valid DNS-1035 label:
      - only lower-case letters, digits or '-'
      - must start with a letter
      - must end with a letter or digit
      EOT
  }
}